1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
|
import com.android.build.gradle.internal.api.BaseVariantOutputImpl
import java.io.FileOutputStream
plugins {
id("com.android.application") version "8.13.0"
}
dependencies {
implementation("androidx.window:window-java:1.3.0")
implementation("androidx.core:core:1.16.0")
testImplementation("junit:junit:4.13.2")
}
android {
namespace = "juloo.keyboard2"
compileSdkVersion = "android-35"
defaultConfig {
applicationId = "juloo.keyboard2"
minSdk = 21
targetSdk { version = release(35) }
versionCode = 50
versionName = "1.32.1"
}
sourceSets {
named("main") {
manifest.srcFile("AndroidManifest.xml")
java.srcDirs("srcs/juloo.keyboard2")
res.srcDirs("res", "build/generated-resources")
assets.srcDirs("assets")
}
named("test") {
java.srcDirs("test")
}
}
signingConfigs {
// Debug builds will always be signed. If no environment variables are set, a default
// keystore will be initialized by the task initDebugKeystore and used. This keystore
// can be uploaded to GitHub secrets by following instructions in CONTRIBUTING.md
// in order to always receive correctly signed debug APKs from the CI.
named("debug") {
storeFile = file(System.getenv("DEBUG_KEYSTORE") ?: "debug.keystore")
storePassword = System.getenv("DEBUG_KEYSTORE_PASSWORD") ?: "debug0"
keyAlias = System.getenv("DEBUG_KEY_ALIAS") ?: "debug"
keyPassword = System.getenv("DEBUG_KEY_PASSWORD") ?: "debug0"
}
create("release") {
val ks = System.getenv("RELEASE_KEYSTORE")
if (ks != null) {
storeFile = file(ks)
storePassword = System.getenv("RELEASE_KEYSTORE_PASSWORD")
keyAlias = System.getenv("RELEASE_KEY_ALIAS")
keyPassword = System.getenv("RELEASE_KEY_PASSWORD")
}
}
}
buildTypes {
named("release") {
isMinifyEnabled = true
isShrinkResources = true
isDebuggable = false
proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"))
resValue("string", "app_name", "@string/app_name_release")
signingConfig = signingConfigs["release"]
}
named("debug") {
isMinifyEnabled = false
isShrinkResources = false
isDebuggable = true
applicationIdSuffix = ".debug"
resValue("string", "app_name", "@string/app_name_debug")
resValue("bool", "debug_logs", "true")
signingConfig = signingConfigs["debug"]
}
}
// Name outputs after the application ID.
android.applicationVariants.forEach { variant ->
variant.outputs.forEach {
it as BaseVariantOutputImpl
it.outputFileName = "${variant.applicationId}.apk"
}
}
compileOptions {
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
}
}
val buildKeyboardFont by tasks.registering(Exec::class) {
val `in` = projectDir.resolve("srcs/special_font")
val out = layout.projectDirectory.file("assets/special_font.ttf")
inputs.dir(`in`)
outputs.file(out)
doFirst { println("\nBuilding assets/special_font.ttf") }
workingDir = `in`
val svgFiles = `in`.listFiles()!!.filter {
it.isFile && it.name.endsWith(".svg")
}.toTypedArray()
commandLine("fontforge", "-lang=ff", "-script", "build.pe", out.asFile.absolutePath, *svgFiles)
}
val genEmojis by tasks.registering(Exec::class) {
doFirst { println("\nGenerating res/raw/emojis.txt") }
workingDir = projectDir
commandLine("python", "gen_emoji.py")
}
val genLayoutsList by tasks.registering(Exec::class) {
inputs.dir(projectDir.resolve("srcs/layouts"))
outputs.file(projectDir.resolve("res/values/layouts.xml"))
doFirst { println("\nGenerating res/values/layouts.xml") }
workingDir = projectDir
commandLine("python", "gen_layouts.py")
}
val checkKeyboardLayouts by tasks.registering(Exec::class) {
inputs.dir(projectDir.resolve("srcs/layouts"))
inputs.file(projectDir.resolve("srcs/juloo.keyboard2/KeyValue.java"))
outputs.file(projectDir.resolve("check_layout.output"))
doFirst { println("\nChecking layouts") }
workingDir = projectDir
commandLine("python", "check_layout.py")
}
val compileComposeSequences by tasks.registering(Exec::class) {
val `in` = projectDir.resolve("srcs/compose")
val out = projectDir.resolve("srcs/juloo.keyboard2/ComposeKeyData.java")
inputs.dir(`in`)
outputs.file(out)
doFirst { println("\nGenerating $out") }
val sequences = `in`.listFiles { it: File ->
!it.name.endsWith(".py") && !it.name.endsWith(".md")
}!!.map { it.absolutePath }.toTypedArray()
workingDir = projectDir
commandLine("python", `in`.resolve("compile.py").absolutePath, *sequences)
doFirst { standardOutput = FileOutputStream(out) }
}
tasks.withType(Test::class).configureEach {
dependsOn(genEmojis, genLayoutsList, checkKeyboardLayouts, compileComposeSequences)
}
val initDebugKeystore by tasks.registering(Exec::class) {
doFirst { println("Initializing default debug keystore") }
isEnabled = !file("debug.keystore").exists()
// A shell script might be needed if this line requires input from the user
commandLine("keytool", "-genkeypair", "-dname", "cn=d, ou=e, o=b, c=ug", "-alias", "debug", "-keypass", "debug0", "-keystore", "debug.keystore", "-keyalg", "rsa", "-storepass", "debug0", "-validity", "10000")
}
// latn_qwerty_us is used as a raw resource by the custom layout option.
val copyRawQwertyUS by tasks.registering(Copy::class) {
from("srcs/layouts/latn_qwerty_us.xml")
into("build/generated-resources/raw")
}
val copyLayoutDefinitions by tasks.registering(Copy::class) {
from("srcs/layouts")
include("*.xml")
into("build/generated-resources/xml")
}
tasks.named("preBuild") {
dependsOn(initDebugKeystore, copyRawQwertyUS, copyLayoutDefinitions, compileComposeSequences)
}
|
